As MacDonald notes in his book, there are basically three steps to accomplish this:

1. Set the OwnerDraw property to True for each menu item where you plan to code your own custom text and graphics.
2. Handle the MeasureItem event.
3. Handle the DrawItem event.

Private Sub mnuTopGreatSite_MeasureItem( _
    ByVal sender As Object, _
    ByVal e As _
        System.Windows.Forms.MeasureItemEventArgs) _
    Handles mnuTopGreatSite.MeasureItem
    Dim mnuItem As MenuItem = CType(sender, MenuItem)
    Dim MenuFont As New Font("Forte", 12)
    e.ItemHeight = _
    e.Graphics.MeasureString(mnuItem.Text, _
        MenuFont).Height + 25
    e.ItemWidth = _
        e.Graphics.MeasureString(mnuItem.Text, _
        MenuFont).Width + 130
End Sub

Private Sub mnuTopGreatSite_DrawItem( _
    ByVal sender As Object, _
    ByVal e As _
    System.Windows.Forms.DrawItemEventArgs) _
    Handles mnuTopGreatSite.DrawItem
    Dim mnuItem As MenuItem = CType(sender, MenuItem)
    Dim mnuFont As New Font("Forte", 12)
    Dim mnuImage As Image = _
        Image.FromFile("\about.jpg")
    e.Graphics.DrawImage(mnuImage, _
        e.Bounds.Left, e.Bounds.Top)
    e.Graphics.DrawString( _
        mnuItem.Text, mnuFont, _
        New SolidBrush(Color.Red), _
        e.Bounds.Left + 135, e.Bounds.Top + 18)
End Sub

If the OwnerDraw property of a menu item set to true, the event MeasureItem is raised before the menu is drawn to allow for the size of the menu item to be specified. We create a font here just to make it available for measurements. We add some space since we know that a graphic will be used when the menu item is actually drawn.

The DrawItem event is raised when a request is made to actually draw the menu item. There are two parts to drawing the menu item in our code: draw the graphic (e.Graphics.DrawImage) and draw the text (e.Graphics.DrawString).

So when you're creating a great "main course" system, Visual Basic .NET will give you a menu to match.